# Maintainer: Ciriaco Garcia de Celis <cgarcia at etherpilot.com>
pkgname=apache-qpid-cpp
pkgver=0.16
pkgrel=2
pkgdesc="apache qpid C++ broker and client"
arch=('i686' 'x86_64')
url="http://qpid.apache.org/index.html"
license=('APACHE')
makedepends=('util-linux' 'boost' 'python2')
depends=('boost')
optdepends=()
source=("http://www.eu.apache.org/dist/qpid/$pkgver/qpid-cpp-$pkgver.tar.gz")
md5sums=('0be857cfc7615763e9296955d33972d5')

build() {
  cd "$srcdir/qpidc-$pkgver"
  sed -i '1 s/python$/python2/' \
    src/tests/ha_tests.py \
    src/tests/long_cluster_tests.py \
    src/tests/cluster_test_logs.py \
    src/tests/cluster_tests.py \
    src/tests/qpid-ctrl \
    src/tests/header_test.py \
    src/tests/qpid-cpp-benchmark \
    bindings/qmf/tests/python_console.py \
    bindings/qmf/tests/python_agent.py \
    managementgen/qmf-gen

  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var
  make all
}

package() {
  cd "$srcdir/qpidc-$pkgver"

  make DESTDIR="$pkgdir/" install
}

# vim:set ts=2 sw=2 et: